다디_ 0

전사 매크로에서 가장 중요한건 stance, 즉 태세를 잘 알아야 한다는겁니다.
stance:1 = 전투 태세
stance:2 = 방어 태세
stance:3 = 광폭 태세
*스텐스 번호들은 고유번호가 아닙니다. 방어 태세를 배우지 않은 전사에겐 광폭 태세가 stance:2입니다.

#show 기술명 은 ? 아이콘을 사용했을때 ? 대신 해당 기술 아이콘을 보여줍니다.
#showtooltip 기술명 은 ? 아이콘을 사용했을때 ? 대신 해당 기술 아이콘과 그 기술의 정보를 보여줍니다.

자동 공격

공격시작
/startattack
공격중지
/stopattack

무기 스왑

쌍수 <-> 양손
/equipslot 16 주무기 이름
/equipslot 17 보조무기 이름
/equipslot 16 양손무기 이름 

예)
/equipslot 16 크룰쇼루크 - 혼돈의 서슬
/equipslot 17 굴하지 않는 힘의 도끼
/equipslot 16 아쉬칸디 - 기사단의 대검

검방, 쉬프트 클릭시 쌍수, 알트 클릭시 검과 저항 방패 착용
/equipslot 16 주무기 이름
/equipslot 17 주방패 이름
/equipslot [modifier:ctrl] 17 보조무기 이름
/equipslot [modifier:alt] 17 저항 방패 이름

팁: 무기 이름은 정확하게 넣어야 하기떄문에 편하게 넣는 방법은 매크로를 작정중인 상태에서 인벤토리나 캐릭터 창에서 무기를 쉬프트 클릭 하면 매크로에 이름이 넣어집니다.

스탠스 댄스 - 태세 전환

전사는 특정 태세에서만 쓸수 있는 기술들이 상당히 많기때문에 태세 전환을 많이 하게 됩니다. 그럴떄 쓰는 매크로 입니다. 포멧은 기술을 사용할수 있는 태세에 있다면 기술을 사용, 아니라면 해당 태새로 전환하는 방식입니다.
/cast [stance:X] 기술명; 태세 전환
예)
/cast [stance:1] 제압; 전투 태세
예2)
/cast [stance:2] 도발; 방어 태세
다른 기술들도 이런식으로 응용해서 사용할수 있습니다.

무장 해제
# show 무장 해제
/cast [nostance:2] 방어 태세; 무장 해제
무장 해제후 광폭 태세로 전환하려면
/cast [nostance:3] Berserker Stance

캐스팅 끊기
/cast [stance:1/2,noequipped:Shields] 광폭 태세; [stance:1/2,equipped:Shields] 방패 가격; [stance:3] 자루 공격
광폭 태세라면 자루 공격을 사용, 광폭 태세가 아니고 방패를 끼고 있다면 방패 가격, 방패를 안끼고 있다면 광폭 태세

공포춤 - 오닉시아 같은 공포를 쓰는 몹과 싸울때 사용
# showtooltip 광전사의 격노
/cast [stance:3] 광전사의 격노; 광폭 태세
/cast 방어 태세

넉백-봉쇄
#showtooltip 봉쇄
/cast [stance:2] 봉쇄; 광폭 태세
/cast 방어 태세

주문 반사
/cast [stance:1/2,equipped:Shields] 주문 반사; [stance:3] 방어 태세
/stopmacro [equipped:Shields]
/equip 방패 이름
광태가 아니고 방패를 끼고 있다면 주문 반사, 광태라면 방태로 전환, 방패가 없다면 방패 착용 합니다.

가로막기
/cast [nostance:2] 방어 태세; [help] 가로막기; [target=targettarget, help] 가로막기
방태가 아니라면 방태, 아군이라면 가로막기, 타겟이 아군이 아니라면 타겟의 타겟이 아군이라면 가로막기 사용합니다.
/cast [target=mouseover,help,nodead,stance:2] 가로막기; 방어 태세
마우스오버로 확인해서 아군이고, 죽지 않았고, 방어태세라면 가로막기 사용, 아니라면 방어 태세 사용합니다.

돌진/봉쇄
/cast [nocombat,stance:1] 돌진; [combat,nostance:3] 광폭 태세; [nocombat,nostance:1] 전투 태세; [combat,stance:3] 봉쇄
돌진/봉쇄 또는 전투상태인지 비전투 상태인지를 확인후 태세변환
/dismount
를 윗줄에 넣어서 사용해도 됩니다.

돌진/봉쇄/가로막기
/cast [help,stance:2,target=targettarget]가로막기;[help,stance:2]가로막기; [help,nostance:2]방어 태세; [combat,harm,nostance:3]광폭 태세;[nocombat,nostance:1]전투 태세;[combat,harm,stance:3]봉쇄;[nocombat,stance:1]돌진

원샷투킬 - 한번 클릭으로 두가지 기술 사용하기

방가&영격
/cast 방어구 가르기
/stopcasting
/cast 영웅의 일격

복수&방막
/cast 복수
/stopcasting
/cast 방패 막기

IWIN 버튼
/use 13
/use 14
/stopcasting
/cast 죽음의 소원
사실... 전사는 뭘써도 I win 버튼이라고 하기 힘들지만, (마법사의 아케인>잔달라>냉정>불작 등에 비해) 장신구1 이나 2 중 사용가능한 장신구를 사용한후 죽음의 소원을 사용합니다. 장신구는 두개를 한꺼번에 못쓰기 때문에 만약 장신구1과 2가 둘다 사용가능한 장신구라면 1을 사용하게 됩니다. 13은 윗 장신구, 14는 아래 장신구. 죽음의 소원이 없다면 무모한 희생으로 바꿔도 됩니다. 무모한 희생 쿨타임 동안엔 장신구만 작동합니다.

멀티 탱킹
#show 방어구 가르기
/cast [target=mouseover, harm, nodead] 방어구 가르기; 방어구 가르기
마우스 포인터를 갖다댔을때, 대상이 적이고 살아있다면 그 대상에게 방가를 사용합니다. 그렇지 않다면 타겟에게 방가를 사용합니다. 장점은 타겟을 바꾸지 않고도 다른 몹에게 방가를 사용할수 있다는점과 방가 자체는 데미지가 없기때문에 양등 메즈된 몹에게 쓰게 되어도 메즈를 깨지 않는다는점입니다. 단점은 마우스 포인터를 신경써줘야한다는점. 멀리 있는 몹에게 마우스 포인터가 가 있는체로 매크로를 사용하면 적이 멀다는 메세지만 보게됩니다.

최후의 저항
/castsequence 생명의 보석, 최후의 저항
처음 클릭하면 생명의 보석을 사용하고 두번 클릭하면 최후의 저항을 사용합니다.
castsequence가 편리하긴 한데, 전사에겐 쓸만한게 없더군요. 전사는 기술 하나하나가 워낙 조건이 많아서. 일단 기본적으로 거의 모든 기술이 분노를 필요로 하는데, 다른 직업은 다 꽉찼다가 밑으로 내려가지만 전사는 0에서 시작하는데다가 분노가 널뛰듯이 오르락 내리락 하기때문에 castsequence를 써먹을데가 없더군요. 

광역 어그로
/castsequence 사기의 외침, 천둥 벼락, 날카로운 고함

공포붕대
#Show 위협의 외침
/cast 위협의 외침
/stopcasting
/targetlasttarget
/use [target=player] 두꺼운 황천매듭 붕대
/targetlasttarget
/startattack
위협의 외침을 쓴후, 자신에게 두꺼운 황천매듭 붕대를 감습니다. 그후 공격하던 적은 다시 타겟팅한후 자동공격을 시작합니다. targetlasttarget이 두번들어간 까닳이, 이상하게 한번만 넣으면 작동을 제데로 안하더군요. 그문제 때문에 낭비한 붕대만도 후..
충격의 일격이 있다면 위협의 외침대신 충격의 일격을 넣어도 됩니다.

램덤 

죽격마격
#show 죽음의 일격
/castrandom 죽음의 일격, 마무리 일격
즉시시전 기술 두가지를 번갈아 사용하려면 castrandom을 사용해야합니다. 문제는. castrandom은 굉장히 단순하게 작동된다는 점입니다. 예를 들어, 적의 피가 많아서 마격이 나갈수 없는 상황에 죽격이 활성화 되어도 정말로 랜덤하게 마격을 사용할려고 하기도 합니다. 반대의 경우도 마찮가지구요. 죽격 쿨타임에 죽격을 쓰려고 할떄도 있고. 즉, 키 연타를 자주 하는 습관이라면 쓸만하지만, 연타가 불편하다면 castrandom은 왠만해서 사용하지 말길 권합니다.

피갈마격
#show 피의 갈증
/castrandom [modifier:shift] 제압; 피의 갈증, 마무리 일격
/stopcasting
/cast 영웅의 일격
쉬프트 클릭 하면 제압, 그냥 누르면 피갈과 마격중 하나를 쓰고 영격을 씁니다. 피갈과 마격이 무슨 이유든 실패하면 (대부분 castrandom의 문제) 영격만 나갑니다.

파티/레이드

지휘&전투의 외침
/cast [group:party/raid] 지휘의 외침; 전투의 외침
파티나 공격대에 속해있다면 지휘의 외침을 사용하고, 아니라면 전투의 외침을 사용합니다